feat: add support for nix users

default.nix

@@ -0,0 +1,36 @@
+{
+  lib,
+  buildGo125Module,
+  version,
+  ...
+}:
+let
+  pname = "brev";
+in
+buildGo125Module {
+  inherit version pname;
+  src = ./.;
+
+  env.CGO_ENABLED = 1;
+  hardeningDisable = [ "bindnow" ];
+  subPackages = [ "." ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/brevdev/brev-cli/pkg/cmd/version.Version=${version}"
+  ];
+
+  vendorHash = "sha256-rB6uqkpnc+SlbzNvtTOnDCIJIpxoiyPb/lsiRYkDltg=";
+
+  postInstall = ''
+    mv $out/bin/brev-cli $out/bin/brev
+  '';
+
+  meta = {
+    description = "CLI tool for managing workspaces provided by brev.nvidia.com";
+    homepage = "https://docs.nvidia.com/brev/latest/";
+    license = lib.licenses.mit;
+    mainProgram = pname;
+  };
+}

flake.nix

@@ -1,20 +1,44 @@
 {
-  description = "golang instance ";
-  
-inputs = {
+  description = "NVIDIA Brev CLI";
+
+  inputs = {
     flake-utils.url = "github:numtide/flake-utils";
     nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
+    treefmt-nix.url = "github:numtide/treefmt-nix";
   };
 
-  outputs = { self, nixpkgs, flake-utils }:
-     flake-utils.lib.eachDefaultSystem
-       (system:
-         let pkgs = nixpkgs.legacyPackages.${system}; in
-         {
-          devShell = import ./shell.nix { inherit pkgs system; };
-          shellHook = ''
-            echo "hallo"
-          '';
-         }
-       );
+  outputs =
+    {
+      self,
+      nixpkgs,
+      flake-utils,
+      treefmt-nix,
+    }:
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = nixpkgs.legacyPackages.${system};
+        version = self.shortRev or self.dirtyShortRev or "dev";
+        brev-cli = pkgs.callPackage ./default.nix { inherit version; };
+        treefmtEval = treefmt-nix.lib.evalModule pkgs {
+          projectRootFile = "flake.nix";
+          programs.nixfmt.enable = true;
+        };
+      in
+      {
+        formatter = treefmtEval.config.build.wrapper;
+
+        packages = {
+          default = brev-cli;
+          inherit brev-cli;
+        };
+
+        apps.default = flake-utils.lib.mkApp {
+          drv = brev-cli;
+        };
+
+        devShells.default = import ./shell.nix { inherit pkgs system; };
+        devShell = self.devShells.${system}.default;
+      }
+    );
 }

shell.nix

@@ -1,37 +1,16 @@
-{ system ? builtins.currentSystem, pkgs ? import <nixpkgs> { inherit system; } }:
+{ pkgs }:
 
-with pkgs;
-let
-    pkgs = import (builtins.fetchGit {
-         # Descriptive name to make the store path easier to identify                
-         name = "my-old-revision";                                                 
-         url = "https://github.com/NixOS/nixpkgs/";                       
-         ref = "refs/heads/nixpkgs-unstable";                     
-         rev = "ff8b619cfecb98bb94ae49ca7ceca937923a75fa";                                           
-    #  }) {};    
-     }) {
-      inherit system;
-    };                                                                         
-    flake-utils = {
-      url = "github:numtide/flake-utils";
-      inputs.nixpkgs.follows = "nixpkgs";
-    };
-     olderVersionOfGolangci-lint = pkgs.golangci-lint;
-    #  system = builtins.currentSystem;
-in
-          mkShell {
-            nativeBuildInputs = [
-              go_1_19
-              gopls
-              tmux
-              gofumpt
-              olderVersionOfGolangci-lint
-              gosec
-              delve
-              go-tools
-              gotests
-              gomodifytags
-            ];
-            # pkgs.system="x86_64-linux";
-          }
-        # )
+pkgs.mkShell {
+  packages = with pkgs; [
+    go
+    gopls
+    tmux
+    gofumpt
+    golangci-lint
+    gosec
+    delve
+    gotools
+    gotests
+    gomodifytags
+  ];
+}